Dear Guillermo,
> In estimating the shelf life of foods a common practice is to store
the
> food at high temperatures (for example, 35C, 45C and 60C) and
> then extrapolate the prediction to 20C. One of the equations used to
> do this is the following:
> RF= RFo + k.exp(-Ea/T). t
>
> Where response variable: RF= rancid flavor
> Explanatory variables: T= temperature, and t= storage time.
> Equation parameters: RFo= inicial rancid flavor, k= rate constant,
> Ea= activation energy
>
> The above equation is non-linear in Ea and I have used
> FITNONLINEAR to estimate the equation parameters to satisfaction.
>
> Now I want to use the equation to estimate RF for T=20C at a given
> storage time. Is there any way I can estimate confidence intervals
> for this prediction?
The function you need is RFUNCTION. This is best illustrated by example.
This example fits a function, and then uses RFUNCTION to calculate
approx
standard errors for a range of fitted values, and also uses it to
calculate
the standard error for a function of the parameters. You need to set up
expressions for these calculations and use these with RFUNCTION (as
shown).
VARIATE [nvalues=18] X;
!(0.204,-0.096,-0.397,-0.698,-0.999,-1.300,-1.602, \
-1.903,-2.204,0.204,-0.096,-0.397,-0.698,-0.999,-1.300,-1.602,-1.903,-2.
204)
VARIATE [nvalues=18] Y; !(16.187,15.531,14.683,12.049,7.681,6.381,2.586,
\
0.959,0.523,18.672,16.674,12.344,13.884,9.769,5.684,1.677,1.095,-0.141)
EXPRESSION [VALUE = Fit = B + (M - B)/(1+ EXP(beta - gamma*X))] model
"Fit a Non-Linear Model"
MODEL [DISTRIBUTION=normal; DISPERSION=*] Y; FITTED=Fit
RCYCLE [MAXCYCLE=100; METHOD=GaussNewton] B,M,beta,gamma; LOWER=*,*,*,*;
UPPER=*,*,\
*,*; STEP=*,*,*,*; INITIAL=1,1,1,1
FITNONLINEAR [PRINT=model,summary,estimates; CALC=model;
CONSTANT=estimate; FPROB=yes]
RKEEP FITTEDVALUES=Fitted; ESTIMATES=Parms; SE=SEParms; DF=DF
SCALAR B,M,beta,gamma; #Parms
SCALAR N; 100
CALC MinX = MIN(X)
& MaxX = MAX(X)
& Fit_X = MinX + (MaxX - MinX)*!(0...N)/100
& N1 = N + 1
VARIATE [N1] Fit_Y,Fit_SE
EXPRESSION [VALUE = MFit = B + (M - B)/(1 + EXP(beta - gamma*x))] fmodel
FOR [NTIMES=N1;INDEX=i]
CALC x = Fit_X$[i]
RFUNCTION [PRINT=*;CALC=fmodel;SE=MF_se] MFit
CALC (Fit_Y,Fit_SE)$[i] = MFit,MF_se
ENDFOR
CALC CI_Lo,CI_Hi = Fit_Y + (-1,1)*Fit_SE*EDT(0.975;DF)
EXPRESSION [VALUE=EC50 = 10**(beta/gamma)] ec50_calc
RFUNCTION [PRINT=e,se;CALC=ec50_calc] EC50
FRAME [RESET=yes] WINDOW=3; BOX=omit
XAXIS [RESET=yes] WINDOW=3; TITLE='X';
YAXIS [RESET=yes] WINDOW=3; TITLE='Y'
PEN [RESET=yes] 1; METHOD=point; SYMBOL=2; CSYMBOL=2; CFILL=2;
COLOUR=2
PEN [RESET=yes] 2...4; METHOD=monotonic; SYMBOL=0; CLINE=4,12,12;
THICKNESS=5,2,2; LINESTYLE=1,2,2
DGRAPH [WINDOW=3; TITLE='Fitted vs Observed';Key=0]
Y=Y,Fit_Y,CI_Lo,CI_Hi; X=X,3(Fit_X); \
DESC='Data','Fitted','95% CI',' '
Regards,
David
_________________________________________________________
Dr David Baird, Biometrician EMail: [log in to unmask]
Mail: AgResearch, PO Box 60, Gerald St, Lincoln, NEW ZEALAND
Phone: +64 3 983 3975 Fax: +64 3 983 3946
=======================================================================
Attention: The information contained in this message and/or attachments
from AgResearch Limited is intended only for the persons or entities
to which it is addressed and may contain confidential and/or privileged
material. Any review, retransmission, dissemination or other use of, or
taking of any action in reliance upon, this information by persons or
entities other than the intended recipients is prohibited by AgResearch
Limited. If you have received this message in error, please notify the
sender immediately.
=======================================================================
|