A few days back I asked a question re choosing hyperpriors for b[i]
(structured heterogeneity) and h[i] (unstructured heterogeneity) in a
spatial regression analysis. I found an excellent discussion of this subject
in Mollie's chapter in Elliott, Wakefield, Best and Briggs (eds) 'Spatial
Epidemiology' (Chapter 15, Bayesian mapping of Hodgkin's disease in France).
Well worth a read.
Key points are as follows:
- In the absence of information about the relative contributions of the
unstructured and structured heterogeneity terms, it is reasonable to assume
a priori that they have the same strength (aha!)
- Gamma hyperpriors are chosen for tau.b and tau.h with means as follows:
2 * (1.96/a)^2 for tau.h
2/m_bar * (1.96/a)^2 for tau.b
Where m_bar is the average number of neighbours across the study region and
95% of the log relative risks lie in the range (-a to +a). The variances of
both gamma hyperpriors are taken to be large to reflect uncertainty about
the values specified for the prior means.
Worked example:
In my study region, the average number of neighbours is 5. The 95% plausible
range of RRs is 0.9 to 1.2, which gives a ~ 0.14. Using the above
guidelines, gamma hyperpriors were chosen to have a mean of 0.61 for tau.b
and 15 for tau.h. The variance for each was set to 10^4. In WinBUGS, these
were specified as follows:
tau.b ~ dgamma(0.61, 0.008)
tau.h ~ dgamma(15, 0.04)
Have a look at Mollie's chapter for more detail. Benardinelli et al describe
the method I was initially attempting in their appendix to Chapter 16. To
me, the Mollie method is more straightforward.
Regards,
Mark S
=========================================
Original message:
Buggsies,
I'm mapping disease incidence and have been using the Scottish lips example
as the basis for my BUGS code. I have observed and expected disease counts
for each of the 'N' regions in my study area. I have one explanatory
variable (y.tran) and have included structured (b[i]) and unstructured
(h[i]) heterogeneity terms in the model (code shown below).
I'm wondering if someone can help me on my choice of hyperpriors for b[i]
and h[i].
For tau.b, I've looked at the plausible range of relative risk of disease
across my study region and reckon that the 95% CI of relative risk is 0.90
to 1.20. If I assume that the log of the relative risks is approximately
normal, my prior guess at tau.b equals 3.29^2 / (log 1.20/0.90)^2 = 131, so
I've specified tau.b ~ dgamma(131, 1).
Now, I'm wondering ... having been so careful about tau.b ... what do I do
about tau.h? Is it OK to use tau.h ~ dgamma(0.5, 0.0005) which seems to be
so commonly used? Any ideas gratefully received. Will summarise to the list.
=================================================================
# spatial regression code
model {
for(i in 1:N) {
O[i] ~ dpois(mu[i])
log(mu[i]) <- log(E[i]) + theta[i]
theta[i] <- beta0 + (beta1*y.tran[i]) + b[i] + h[i]
RR[i] <- exp(theta[i])
h[i] ~ dnorm(0, tau.h) }
# CAR prior distribution for spatial random effects:
b[1:N]~car.normal(adj[], weights[], num[], tau.b)
for(m in 1:sumNumNeigh) {
weights[m] <- 1
}
beta0 ~ dflat()
beta1 ~ dnorm(0.0, 1.0E-5)
tau.h ~ dgamma(0.5, 0.0005)
tau.b ~ dgamma(131, 1)
# Interpretation of variance parameter
sd.b <- sd(b[])
var.b <- pow(sd.b,2)
sd.h <- sd(h[])
var.h <- pow(sd.h,2)
}
=================================================================
*******************************************
Mark Stevenson
EpiCentre, IVABS
Massey University
Private Bag 11-222 Palmerston North
NEW ZEALAND
Ph: +64 6 350 6149
Fx: +64 6 350 5716
[log in to unmask]
http://www.dairywin.co.nz/
*******************************************
-------------------------------------------------------------------
To mail the BUGS list, mail to [log in to unmask]
You can search old messages at www.jiscmail.ac.uk/lists/bugs.html
To leave the BUGS list, send LEAVE BUGS to [log in to unmask]
If this fails, mail [log in to unmask], NOT the whole list
This list is for discussion of modelling issues and the BUGS
software. For help with crashes and error messages, first mail
[log in to unmask]
|