>Who's to blame?

Sorry, but it is your program that is at fault.

> The NAG compiler is giving me a headache

Actually the NAG compiler has helpfully diagnosed your error!

In fact there are two mistakes in your code...

> subroutine sub(a,b)
> implicit none
> real, intent(in) :: a
> real, intent(out) :: b

According to the Fortran standard, on invocation of SUB, B becomes
undefined. That means you are not allowed to reference its value.
Since B is associated with X (in this discussion I have changed the
name in the main program to avoid confusing SUB:A with main:A),
that means that X becomes undefined. Since X also becomes associated
with A, that means that A is also undefined.

With -nan, the NAG compiler sets B (and thus X, and thus A - because
they are all associated) to a signalling NaN. This detects use of
the undefined variable before it is given a value.

> b = a

If B and A are aliased, this is not allowed regardless of intent;
this is true of Fortran 66, 77, 90, 95, 2003 and the current 2008.

From the Fortran 2008 standard, page 300, section 12.5.2.13
("Restrictions on entities associated with dummy arguments")

  "While an entity is associated with a dummy argument, the
   following restrictions hold.

   (3) Action that affects the value of the entity or any subobject
       of it shall be taken only through the dummy argument unless
       [a set of exceptions that do not apply here]"

...see later

> end subroutine sub
>
> program test
> implicit none
> real :: x

I changed the name to X here to avoid confusion...

> x = 1.0
> call sub(x,x)

Ok, so X will become associated with A, which means that any action
that affects X must be taken through A.

However, X is also associated with B, which means that any action
that affects X must be taken through B.

Clearly it is impossible to satisfy both of these conditions
simultaneously, so that means X is not allowed to be modified at all.
(This is explained in Note 12.34 on page 301.)

In this case, the line in SUB that reads
  "b = a"
affects X, but this action is not being taken through A, thus
violating the first condition, so the program is not standard
conforming.

> write(*,*) x
> end program test

Some people have in fact opined that the very call
    CALL SUB(X,X)
is invalid because the INTENT(OUT) specification is affecting the
variable that has INTENT(IN). However, a close reading of the text
makes me think that it is valid - just not at all useful!

To make this program legal, you need to stop creating the alias,
i.e. do not pass X to two different dummy arguments. This is easy
to do: just parenthesise the X that will be associated with the
INTENT(IN) argument, making it an expression. It will then pass the
original value of X to A, and the variable X to B.

That is,
   CALL SUB((X),X)

(This used to be slightly risky because a small number of older
compilers had optimiser bugs that removed the parentheses ... but it
should be safe these days.)

Hope that helps,

Cheers,
--
.....................Malcolm Cohen, NAG Oxford/Tokyo.