Hi all. I just wanted to let youall know that problems can occur with
seemingly-noninformative inverse-gamma prior distributions for variance
components. In many cases, it's more reliable to simply use uniform
prior distributions on the standard deviation parameters.
We have an example in Appendix C of the second edition of our book,
"Bayesian Data Analysis."
To get this appendix, just go to the bugs.R page
(http://www.stat.columbia.edu/~gelman/bugsR/) and
near the top of the page, there's a place to click to download Appendix C.
For example, in a simple 1-way data structure (the "8 schools" example
from "Bayesian Data Analysis"), we use the following model:
model {
for (j in 1:J){
y[j] ~ dnorm (theta[j], tau.y[j])
theta[j] ~ dnorm (mu.theta, tau.theta)
tau.y[j] <- pow(sigma.y[j], -2)
}
mu.theta ~ dnorm (0, 1.0E-6)
tau.theta <- pow(sigma.theta, -2)
sigma.theta ~ dunif (0, 1000)
}
This is a uniform prior distribution on the the sd parameter
(sigma.theta) and works fine.
An alternative uses the inverse-gamma prior, replacing the last 2 lines
in the above model by,
tau.theta ~ dgamma (1, 1)
sigma.theta <- 1/sqrt(tau.theta)
This does not work well at all (see Figure C.3 on page 597).
- Andrew Gelman
P.S. I'm not trying to knock the inverse-gamma model in general. It
can be very effective, especially when applied hierarchically to several
variance parameters. I'm just making a recommendation for what to do
when a noninformative distribution is required.
-------------------------------------------------------------------
This list is for discussion of modelling issues and the BUGS software.
For help with crashes and error messages, first mail [log in to unmask]
To mail the BUGS list, mail to [log in to unmask]
Before mailing, please check the archive at www.jiscmail.ac.uk/lists/bugs.html
Please do not mail attachments to the list.
To leave the BUGS list, send LEAVE BUGS to [log in to unmask]
If this fails, mail [log in to unmask], NOT the whole list
